make_n1_files.pro (Kronos IDL library)

;+
; Contains the make_n1_files procedure
;
; :Author:
;    Baptiste Cecconi
;
; :History:
;    2004/12/03: Created
;
;    2013/03/01: Last Edit
;-
;
;+
; fabrication et sauvegarde des fichiers N1 a partir des fichiers K
; du (jour,heure) (aaaajjjd,hd) a (aaaajjjf,hf)
; donnees "analyse" seulement
;
; :Uses:
;    delpath, extpath, lit_hfr_1
;
; :Params:
;    aaaajjjd: in, required, type=string
;       date de debut
;    hd:   in, required, type=int
;       heure de debut
;    aaaajjjf: in, required, type=string
;       date de fin
;    hf:       in, required, type=int
;       heure de fin
;-
pro MAKE_N1_FILES, aaaajjjd, hd, aaaajjjf, hf, $
                   verbose=verbose, nodb=nodb

pkfiles=make_file_list(aaaajjjd, hd, aaaajjjf, hf, level='k', /noemptyfiles)
if (ptr_valid(pkfiles) eq 0) then begin
		filenb=0
endif else begin
		kfiles=*pkfiles
		filenb=n_elements(kfiles)
		n1files=strarr(filenb)
		ptr_free, pkfiles
endelse

for i=0, filenb-1 do begin

	fichier=kfiles[i]
	path=EXTPATH(fichier)
	path=strmid(path,0,strlen(path)-2)
	nomfich = path+'n1/R'+strmid(fichier, 9, 10, /reverse_offset)

	print & print,'fichier : ',fichier
	LIT_HFR_1, fichier, z

	if n_elements(z) gt 0 then begin
		data = {data_N1}
		data = replicate(data,n_elements(z))
		data.ti = (z.an-96)*100000000L + z.jour*100000L + $
			reform([3600L,60L,1L]#z.time(0:2))
		data.fi = z.bande*10000000L + long(z.channel/25L)*10000L + $
			z.filters*100L + z.filter
		data.dt = z.msec*10
		w=where(data.dt eq 120)
		if w(0) ne -1 then data(w).dt = 125
		data.c = z.time(3)
		data.ant = z.df
		data.agc1 = z.agc1
		data.agc2 = z.agc2
		data.auto1 = z.auto1
		data.auto2 = z.auto2
		data.cross1 = z.cross1
		data.cross2 = z.cross2
		data.ydh = long(strmid(delpath(kfiles[i]),1,7))*100l+long(strmid(delpath(kfiles[i]),9,2))
		data.num = lindgen(n_elements(data))
		print,'writing ',nomfich,' ...'
		WRITE_DATA_BINARY, nomfich, data
	endif

	n1files[i] = nomfich
endfor

; Update the Kronos Database with the new files
if ~keyword_set(nodb) and filenb ne 0 then begin
	upsert_args = getenv('ROOT_RPWS') + '/pro/kronosdb/upsert.sh'
	if keyword_set(verbose) then upsert_args = [upsert_args, '-v']
	upsert_args = [upsert_args, '-f', n1files]
	spawn, /NOSHELL, upsert_args
end

return
end